共计 1446 个字符，预计需要花费 4 分钟才能阅读完成。
在 Unix 系统环境中可以通过各种 Unix shell 结合 cron 任务实现对 MySQL 的自动备份，那在 Windows 下要如何实现呢，其实很简单只要写好自定义的 batch 脚本在结合 taskschd.msc（任务计划程序），就可以实现，最近需要修改调优 Windows 环境下的 MySQL 就顺便写了一个使用 mysqldump 做逻辑备份的 batch 脚本，如下：
@echo off
::mysql_backup.bat
set hour=%time:~0,2%
if “%time:~0,1%”==” ” set hour=0%time:~1,1%
set now=%Date:~0,4%%Date:~5,2%%Date:~8,2%%hour%%Time:~3,2%%Time:~6,2%
:: 主机 ip
set host=127.0.0.1
:: 端口
set port=3306
:: 用户
set username=root
:: 密码
set password=youpassword
:: 要备份数据库的名字，如果有多个库请用空格分隔
set databasename=database1 database2
:: MySQL Bin 目录
:: 如果在安装配置时添加 MySQL Bin 目录到了环境变量 (PATH)，此处可以留空
set MYSQL=D:\mysql-5.5.57-winx64\bin\
:: 配置 SQL 备份路径
set DIR=D:\backup\db\
:: 创建备份 MySQL 的备份目录
if not exist %DIR% (
mkdir %DIR% 2>nul
)
if not exist %DIR% (
echo Backup path: %DIR% not exists, create dir failed.
goto exit
)
echo start mysqldump …
for %%i in (%databasename%) do (
%MYSQL%mysqldump -h%host% -P%port% -u%username% -p%password% %%i > %DIR%%%i-%now%.sql 2>nul
)
echo end mysqldump
:: 记录主库状态，且做日志记录
%MYSQL%mysql -h%host% -P%port% -u%username% -p%password% -Bse “select now();show master status\G” > %DIR%MySQL_status-%now%.log
echo delete files before 60 days
:: 删除 60 天前的备份
forfiles /p “D:\backup\db” /m *.* /d -60 /c “cmd /c del @file /f”
:exit
在写好 batch 脚本后最后再在 taskschd.msc 中添加每天定时触发执行，具体的配置方法如下：
这里需要注意的是，这里一定要勾选上使用最高权限运行，以免造成运行失败
这里触发条件选择每天一次，具体时间可以视实际生产环境判断，开始任务则为按预定计划
在这里填上 batch 脚本的路径以及初始目录，其中需要注意的是一定需要配置初始目录，不然没有把 batch 脚本添加入 PATH 环境变量中该任务会找不到 batch 脚本从而执行失败
条件这里可以根据实际情况选择
这里一定需要勾选 允许按需运行任务，其他的时间就实际情况而定，最后在确认保存后输入用户密码这样每天系统就会自动做 mysqldump 逻辑备份。
本文永久更新链接地址 ：http://www.linuxidc.com/Linux/2017-08/146485.htm
